49,531 DPS
내 결과와 같은 방식(같은 적, 로테이션 반복)으로, 이 로테이션을 가져온 커뮤니티 gcsim 설정의 빌드를 써서 계산한 점수입니다. 내 빌드의 점수는 다릅니다.
출처에서는 자체 조건의 로테이션 1회 기준 50,326 DPS로 보고합니다.
내 빌드로 계산하기
게임 프로필의 캐릭터 쇼케이스에 넣어 둔 캐릭터만 불러올 수 있습니다. "캐릭터 상세 정보 표시"를 켜 주세요.
출처
로테이션 스크립트 (gcsim)
let crystallize_logic = 2;
let crystallize_delay = 6;
let _pick_up_crystallize = pick_up_crystallize;
fn pick_up_crystallize(element string) {
let result = _pick_up_crystallize(element);
if result { delay(crystallize_delay); }
return result;
}
let _execute_action = execute_action;
fn execute_action(char_id number, action_id number, p map) {
switch crystallize_logic {
case 1: pick_up_crystallize("any");
case 2: switch {
case char_id == .keys.char.fischl && action_id == .action.burst:
pick_up_crystallize("any");
case char_id == .keys.char.noelle && action_id == .action.dash:
pick_up_crystallize("any");
}
}
return _execute_action(char_id, action_id, p);
}
active fischl;
for {
switch {
case .fischl.skill.ready && .fischl.swap.ready && !.fischl.oz:
fischl skill, attack;
case .fischl.burst.ready && .fischl.swap.ready && !.fischl.oz:
fischl attack:2, burst;
case .navia.burst.ready && .navia.swap.ready:
navia burst;
case .furina.burst.ready && .furina.swap.ready:
if .furina.skill.ready { furina skill; }
furina burst;
case .furina.skill.ready && .furina.swap.ready && !.furina.status.furina-skill:
furina skill;
case .navia.skill.ready && .navia.swap.ready && (.navia.shrapnel+.gadgets.crystallizeshard.all >= 6):
if .navia.shrapnel >= 6 {
navia skill;
} else { navia skill[hold=1]; }
navia attack:3;
case .noelle.burst.ready && .noelle.swap.ready && !.noelle.status.noelle-burst:
noelle burst;
case .noelle.skill.ready && .noelle.onfield:
noelle skill;
case .noelle.normal == 4:
noelle dash;
case .noelle.status.noelle-burst:
noelle attack;
case .navia.onfield:
navia attack;
case .noelle.onfield:
noelle attack;
case .fischl.onfield:
fischl attack;
case .furina.onfield:
furina attack;
}
}