Alhaitham / Furina / Sucrose / Kuki Shinobu

45,312 DPS

Tính giống như kết quả của bạn (cùng kẻ địch, lặp lại vòng xoay), dùng build trong cấu hình gcsim của cộng đồng mà vòng xoay này lấy từ đó. Build của bạn sẽ có điểm khác.

Nguồn báo cáo 62,719 DPS cho một vòng xoay theo điều kiện riêng của họ.

Tính với build của bạn

Chỉ có thể tải những nhân vật nằm trong Trưng Bày Nhân Vật ở hồ sơ trong game. Hãy bật "Hiển Thị Chi Tiết Nhân Vật".

Nguồn

https://db.kqm.gg/db/9CGrQkjc6k7W

Kịch bản vòng xoay (gcsim)

fn randy(mean, standardDeviation, min, max, display) {
  let value = randnorm() * standardDeviation + mean;
  if value > max {
    value = max;
  } else if value < min {
    value = min;
  }
  if display {
    print(value);
  }
  return value;
}
let prev_char_id = -1;
let prev_action_id = -1;
let _execute_action = execute_action;
fn execute_action(char_id number, action_id number, p map) {

  if prev_char_id != char_id && action_id != .action.swap {
    execute_action(char_id, .action.swap, []);
  }

  if action_id == .action.swap {
    
    delay(randy(9.5, 1.5, 5, 17, 0));
  } else if prev_action_id == .action.attack && action_id != .action.attack && action_id != .action.charge {
    
    delay(randy(3, 1, 0, 6, 0));
  } else if prev_action_id != .action.attack {
    
    delay(randy(3, 1, 0, 6, 0));
  }
  
  prev_char_id = char_id;
  prev_action_id = action_id;
  return _execute_action(char_id, action_id, p);
}
active kuki;
for let r=0; r<3; r=r+1 {
  kuki skill, dash;
  if !.furina.swap.ready {
    kuki attack;
  }
  
  furina skill, dash;
  while !.furina.burst.ready {
    furina attack;
  }
  furina burst;
  
  sucrose attack;
  if .sucrose.skill.ready {
    sucrose skill, dash;
  } else {
    sucrose attack;
  }

  alhaitham skill[hold=1], low_plunge[short=1],
            attack:4, charge, dash,
            attack:4, charge, dash,
            attack:3, charge;
            
  kuki skill, dash, attack;
  
  sucrose attack;
  if .sucrose.skill.ready {
    sucrose skill, dash;
  } else {
    sucrose attack;
  }

  alhaitham swap;
  while !.alhaitham.burst.ready {
    alhaitham attack;
  }
  alhaitham burst;
  
  kuki swap;
  if .kuki.burst.ready {
    kuki burst;
  } else {
    kuki attack:2;
  }
  
  alhaitham attack:3, dash,
            attack:3, charge, dash,
            attack:4, charge, dash,
            attack:3, charge;
}